Dwbs/common.gradle

// 通用配置67
android {

    // 编译源码版本
    compileSdkVersion 31
    defaultConfig {
        // 最低安装版本
        minSdkVersion 24
        // 目标适配版本
        targetSdkVersion 30
        versionName '0.9.3'
        versionCode 93
    }

    // 支持 Java JDK 8
    compileOptions {
        targetCompatibility JavaVersion.VERSION_1_8
        sourceCompatibility JavaVersion.VERSION_1_8
    }

    sourceSets {
        main {
            jniLibs.srcDirs = ['libs']
        }
    }

    // 可在 Studio 最左侧中的 Build Variants 选项中切换默认的构建类型

    buildTypes {
        // 调试版本
        debug {}
        // 预览版本
        preview {}
        // 正式版本
        release {}
    }

    // 代码警告配置
    lintOptions {
        // 禁用文本硬编码警告
        disable 'HardcodedText'
        // 禁用图片描述警告
        disable 'ContentDescription'
    }

}

afterEvaluate {
    // 前提条件是这个 Module 工程必须是 Library 类型，并且排除名为 umeng 的 Module 工程
    if (android.defaultConfig.applicationId == null && "umeng" != getName()) {
        // 排除 BuildConfig.class
        generateReleaseBuildConfig.enabled = false
        generatePreviewBuildConfig.enabled = false
        generateDebugBuildConfig.enabled = false
    }
}

dependencies {
    // 依赖 libs 目录下所有的 jar 和 aar 包
    implementation fileTree(include: ['*.jar', '*.aar'], dir: 'libs')

    // AndroidX 库：https://github.com/androidx/androidx
    implementation 'androidx.appcompat:appcompat:1.4.2'

    // Material 库：https://github.com/material-components/material-components-android
    implementation 'com.google.android.material:material:1.6.0'

    // 工具类：https://github.com/Blankj/AndroidUtilCode
    implementation 'com.blankj:utilcodex:1.31.0'
    //LiveBus: https://github.com/JeremyLiao/LiveEventBus
    implementation 'io.github.jeremyliao:live-event-bus-x:1.8.0'


    // 依赖lancet-all, 则包含所有lancet能力
    implementation "com.bytedance.tools.codelocator:codelocator-core:2.0.0"
    debugImplementation "com.bytedance.tools.codelocator:codelocator-lancet-all:2.0.0"
    debugImplementation 'com.github.ChickenHook:RestrictionBypass:2.2'

    previewImplementation "com.bytedance.tools.codelocator:codelocator-lancet-all:2.0.0"
    previewImplementation 'com.github.ChickenHook:RestrictionBypass:2.2'


}